# 
# lib3dObjects build system
#
PROJECT(lib3dObjects)

CMAKE_MINIMUM_REQUIRED(VERSION 2.8)

set(LIB3DOBJECTS_VERSION 20160831.0.0)

#--------------------------------#
# Enforce an out-of-source build #
#--------------------------------#

STRING(COMPARE EQUAL "${PROJECT_SOURCE_DIR}" "${PROJECT_BINARY_DIR}" INSOURCE)
IF(INSOURCE)
  MESSAGE(FATAL_ERROR "This project requires an out of source build. This is handled by the Makefile. Please type 'make'.")
ENDIF(INSOURCE)


#--------------------------------#
# Build Options                  #
#--------------------------------#

# this gets CMake to use the system triplet (x86_64-linux-gnu)
# for library locations
INCLUDE(GNUInstallDirs)

# Options can be set from the command line when running cmake.
#   eg. cmake . -DCMAKE_BUILD_TYPE=Release -DDEBUG_PROFILING=on

# Build types are: Release, Debug, RelWithDebInfo, MinSizeRel
IF( NOT CMAKE_BUILD_TYPE )
  SET( CMAKE_BUILD_TYPE Release CACHE STRING
       "Build type options are: None Debug Release RelWithDebInfo MinSizeRel."
       FORCE )
ENDIF( NOT CMAKE_BUILD_TYPE )


#-----------------------#
# Dependencies          #
#-----------------------#

# OpenCV
FIND_PACKAGE(OpenCV REQUIRED)

#-----------------------#
# Compiler setup        #
#-----------------------#

ADD_DEFINITIONS( "-Wall" )
INCLUDE_DIRECTORIES( ${PROJECT_SOURCE_DIR}/include 
                     ${OPENCV_INCLUDE_DIRS} )

LINK_DIRECTORIES( ${OPENCV_LIBRARY_DIRS} )


#-----------------------#
# Installation Setup    #
#-----------------------#

# An alternative installation location can be specified by using
# -DCMAKE_BUILD_TYPE=<build_type> when running cmake

IF( NOT CMAKE_INSTALL_PREFIX )
   SET( CMAKE_INSTALL_PREFIX "/usr/local" )
ENDIF( NOT CMAKE_INSTALL_PREFIX )


#-----------------------#
# Print Some Info       #
#-----------------------#

MESSAGE( "" )
MESSAGE( "CONFIGURATION SUMMARY" )
MESSAGE( "---------------------" )
MESSAGE( "" )
MESSAGE( "CMAKE_BUILD_TYPE = '${CMAKE_BUILD_TYPE}'" )
MESSAGE( "" )
MESSAGE( "CMAKE_INSTALL_PREFIX = '${CMAKE_INSTALL_PREFIX}'" )
MESSAGE( "" )

IF( CMAKE_BUILD_TYPE STREQUAL Debug )
   MESSAGE( "CMAKE_CXX_FLAGS_DEBUG = '${CMAKE_CXX_FLAGS_DEBUG}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Debug )

IF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )
   MESSAGE( "CMAKE_CXX_FLAGS_RELWITHDEBINFO = '${CMAKE_CXX_FLAGS_RELWITHDEBINFO}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )

IF( CMAKE_BUILD_TYPE STREQUAL Release )
   MESSAGE( "CMAKE_CXX_FLAGS_RELEASE = '${CMAKE_CXX_FLAGS_RELEASE}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Release )

IF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )
   MESSAGE( "CMAKE_CXX_FLAGS_MINSIZEREL = '${CMAKE_CXX_FLAGS_MINSIZEREL}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )


#-----------------------#
# Build Instructions    #
#-----------------------#

# Locations for the library and binary files
SET( LIBRARY_OUTPUT_PATH     ${PROJECT_SOURCE_DIR}/lib )
SET( EXECUTABLE_OUTPUT_PATH  ${PROJECT_SOURCE_DIR}/bin )

ADD_SUBDIRECTORY(src)
ADD_SUBDIRECTORY(include)
ADD_SUBDIRECTORY(utils)


#-----------------------#
# Installation Related  #
#-----------------------#

INCLUDE(CMakePackageConfigHelpers)
WRITE_BASIC_PACKAGE_VERSION_FILE(
    "${CMAKE_CURRENT_BINARY_DIR}/Lib3dObjects/Lib3dObjectsConfigVersion.cmake"
    VERSION ${LIB3DOBJECTS_VERSION}
    COMPATIBILITY AnyNewerVersion
)

IF(CMAKE_VERSION VERSION_LESS "3.0")
    EXPORT(TARGETS 3dObjects
        FILE "${CMAKE_CURRENT_BINARY_DIR}/Lib3dObjects/Lib3dObjectsTargets.cmake"
        NAMESPACE lib3dobjects::
    )
ELSE()
    EXPORT(EXPORT Lib3dObjectsTargets
        FILE "${CMAKE_CURRENT_BINARY_DIR}/Lib3dObjects/Lib3dObjectsTargets.cmake"
        NAMESPACE lib3dobjects::
    )
ENDIF()

CONFIGURE_FILE(cmake/Lib3dObjectsConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/Lib3dObjects/Lib3dObjectsConfig.cmake"
    COPYONLY
)

set(ConfigPackageLocation lib/cmake/Lib3dObjects)
install(EXPORT Lib3dObjectsTargets
    FILE Lib3dObjectsTargets.cmake
    NAMESPACE lib3dobjects::
    DESTINATION ${ConfigPackageLocation}
)
install(
    FILES cmake/Lib3dObjectsConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/Lib3dObjects/Lib3dObjectsConfigVersion.cmake"
    DESTINATION "${ConfigPackageLocation}"
)
