# 
# libdeltaT build system
#
# Dependencies
#  * UF (only required for the tool mb83p_to_gsf)
#

PROJECT(libdeltaT)
CMAKE_MINIMUM_REQUIRED(VERSION 2.8)

set(LIBDELTAT_VERSION 20170117.0.0)

#--------------------------------#
# Enforce an out-of-source build #
#--------------------------------#

STRING(COMPARE EQUAL "${PROJECT_SOURCE_DIR}" "${PROJECT_BINARY_DIR}" INSOURCE)
IF(INSOURCE)
  MESSAGE(FATAL_ERROR "This project requires an out of source build. This is handled by the Makefile. Please type 'make'.")
ENDIF(INSOURCE)


#-----------------------#
# Build Options         #
#-----------------------#

# this gets CMake to use the system triplet (x86_64-linux-gnu)
# for library locations
INCLUDE(GNUInstallDirs)

# Options can be set from the command line when running cmake.
#   eg. cmake . -DCMAKE_BUILD_TYPE=Release -DDEBUG_PROFILING=on

# Build types are: Release, Debug, RelWithDebInfo, MinSizeRel
IF( NOT CMAKE_BUILD_TYPE )
  SET( CMAKE_BUILD_TYPE Release CACHE STRING
       "Build type options are: None Debug Release RelWithDebInfo MinSizeRel."
       FORCE )
ENDIF( NOT CMAKE_BUILD_TYPE )


#-----------------------#
# Dependencies          #
#-----------------------#

# Strict aliasing causes lots of warnings with OpenCV and g++-4.1
ADD_DEFINITIONS( "-fno-strict-aliasing" )

# UF
FIND_PACKAGE(UF)
SET( UF_LIBRARY ufGeographicConversions ufGPSParser )  

# libplankton 
FIND_PACKAGE(LibPlankton)

FIND_PACKAGE(Boost COMPONENTS system)

FIND_PACKAGE(LibGSF)

# ulapack 
find_path(ULAPACK_INCLUDE_DIR matrix_types.hpp PATH_SUFFIXES ulapack)
SET( CMAKE_REQUIRED_INCLUDES ${ULAPACK_INCLUDE_DIR})
INCLUDE(CheckIncludeFileCXX)
CHECK_INCLUDE_FILE_CXX("matrix_types.hpp" HAVE_ULAPACK )
IF( NOT HAVE_ULAPACK )
    MESSAGE( FATAL_ERROR  "ERROR - Can't find ulapack - " ${ULAPACK_INCLUDE_DIR} )
ENDIF( NOT HAVE_ULAPACK )

#-----------------------#
# Compiler setup        #
#-----------------------#

ADD_DEFINITIONS( "-Wall" )

INCLUDE_DIRECTORIES(
    ${PROJECT_SOURCE_DIR}/include
    ${ULAPACK_INCLUDE_DIR}
    )


#-----------------------#
# Installation Setup    #
#-----------------------#

# An alternative installation location can be specified by using
# -DCMAKE_BUILD_TYPE=<build_type> when running cmake


#-----------------------#
# Print Some Info       #
#-----------------------#

MESSAGE( "" )
MESSAGE( "CONFIGURATION SUMMARY" )
MESSAGE( "---------------------" )
MESSAGE( "" )
MESSAGE( "CMAKE_BUILD_TYPE = '${CMAKE_BUILD_TYPE}'" )
MESSAGE( "" )
MESSAGE( "CMAKE_INSTALL_PREFIX = '${CMAKE_INSTALL_PREFIX}'" )
MESSAGE( "" )

IF( CMAKE_BUILD_TYPE STREQUAL Debug )
   MESSAGE( "CMAKE_CXX_FLAGS_DEBUG = '${CMAKE_CXX_FLAGS_DEBUG}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Debug )

IF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )
   MESSAGE( "CMAKE_CXX_FLAGS_RELWITHDEBINFO = '${CMAKE_CXX_FLAGS_RELWITHDEBINFO}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )

IF( CMAKE_BUILD_TYPE STREQUAL Release )
   MESSAGE( "CMAKE_CXX_FLAGS_RELEASE = '${CMAKE_CXX_FLAGS_RELEASE}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Release )

IF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )
   MESSAGE( "CMAKE_CXX_FLAGS_MINSIZEREL = '${CMAKE_CXX_FLAGS_MINSIZEREL}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )


#-----------------------#
# Build Instructions    #
#-----------------------#

ADD_SUBDIRECTORY(src)
ADD_SUBDIRECTORY(include)
ADD_SUBDIRECTORY(tools)

#-----------------------#
# Testing Instructions  #
#-----------------------#

INCLUDE(CMakePackageConfigHelpers)
WRITE_BASIC_PACKAGE_VERSION_FILE(
    "${CMAKE_CURRENT_BINARY_DIR}/LibDeltaT/LibDeltaTConfigVersion.cmake"
    VERSION ${LIBDELTAT_VERSION}
    COMPATIBILITY AnyNewerVersion
)

IF(CMAKE_VERSION VERSION_LESS "3.0")
    EXPORT(TARGETS deltaT
        FILE "${CMAKE_CURRENT_BINARY_DIR}/LibDeltaT/LibDeltaTTargets.cmake"
        NAMESPACE libdeltat::
    )
ELSE()
    EXPORT(EXPORT LibDeltaTTargets
        FILE "${CMAKE_CURRENT_BINARY_DIR}/LibDeltaT/LibDeltaTTargets.cmake"
        NAMESPACE libdeltat::
    )
ENDIF()

CONFIGURE_FILE(cmake/LibDeltaTConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/LibDeltaT/LibDeltaTConfig.cmake"
    COPYONLY
)

set(ConfigPackageLocation lib/cmake/LibDeltaT)
install(EXPORT LibDeltaTTargets
    FILE LibDeltaTTargets.cmake
    NAMESPACE libdeltat::
    DESTINATION ${ConfigPackageLocation}
)
install(
    FILES cmake/LibDeltaTConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/LibDeltaT/LibDeltaTConfigVersion.cmake"
    DESTINATION "${ConfigPackageLocation}"
)
