# 
# libgsf build system
#

PROJECT(libgsf)
CMAKE_MINIMUM_REQUIRED(VERSION 2.8)

set(LIBGSF_VERSION 2.04)

#--------------------------------#
# Enforce an out-of-source build #
#--------------------------------#

STRING(COMPARE EQUAL "${PROJECT_SOURCE_DIR}" "${PROJECT_BINARY_DIR}" INSOURCE)
IF(INSOURCE)
  MESSAGE(FATAL_ERROR "This project requires an out of source build. This is handled by the Makefile. Please type 'make'.")
ENDIF(INSOURCE)


#--------------------------------#
# Build Options                  #
#--------------------------------#

# this gets CMake to use the system triplet (x86_64-linux-gnu)
# for library locations
INCLUDE(GNUInstallDirs)

# Options can be set from the command line when running cmake.
#   eg. cmake . -DCMAKE_BUILD_TYPE=Release -DDEBUG_PROFILING=on

# Build types are: Release, Debug, RelWithDebInfo, MinSizeRel
IF( NOT CMAKE_BUILD_TYPE )
  SET( CMAKE_BUILD_TYPE Release CACHE STRING
       "Build type options are: None Debug Release RelWithDebInfo MinSizeRel."
       FORCE )
ENDIF( NOT CMAKE_BUILD_TYPE )



#-----------------------#
# Compiler setup        #
#-----------------------#

ADD_DEFINITIONS( "-Wall" )



INCLUDE_DIRECTORIES( ${PROJECT_SOURCE_DIR}/include )


#-----------------------#
# Print Some Info       #
#-----------------------#

MESSAGE( "" )
MESSAGE( "CONFIGURATION SUMMARY" )
MESSAGE( "---------------------" )
MESSAGE( "" )
MESSAGE( "CMAKE_BUILD_TYPE = '${CMAKE_BUILD_TYPE}'" )
MESSAGE( "" )
MESSAGE( "CMAKE_INSTALL_PREFIX = '${CMAKE_INSTALL_PREFIX}'" )
MESSAGE( "" )

IF( CMAKE_BUILD_TYPE STREQUAL Debug )
   MESSAGE( "CMAKE_CXX_FLAGS_DEBUG = '${CMAKE_CXX_FLAGS_DEBUG}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Debug )

IF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )
   MESSAGE( "CMAKE_CXX_FLAGS_RELWITHDEBINFO = '${CMAKE_CXX_FLAGS_RELWITHDEBINFO}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )

IF( CMAKE_BUILD_TYPE STREQUAL Release )
   MESSAGE( "CMAKE_CXX_FLAGS_RELEASE = '${CMAKE_CXX_FLAGS_RELEASE}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Release )

IF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )
   MESSAGE( "CMAKE_CXX_FLAGS_MINSIZEREL = '${CMAKE_CXX_FLAGS_MINSIZEREL}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )

MESSAGE( "" )

#-----------------------#
# Build Instructions    #
#-----------------------#

ADD_SUBDIRECTORY(src)
ADD_SUBDIRECTORY(include)

#-----------------------#
# Installation Related  #
#-----------------------#

INCLUDE(CMakePackageConfigHelpers)
WRITE_BASIC_PACKAGE_VERSION_FILE(
    "${CMAKE_CURRENT_BINARY_DIR}/LibGSF/LibGSFConfigVersion.cmake"
    VERSION ${LIBGSF_VERSION}
    COMPATIBILITY AnyNewerVersion
)

IF(CMAKE_VERSION VERSION_LESS "3.0")
    EXPORT(TARGETS gsf
        FILE "${CMAKE_CURRENT_BINARY_DIR}/LibGSF/LibGSFTargets.cmake"
        NAMESPACE libgsf::
    )
ELSE()
    EXPORT(EXPORT LibGSFTargets
        FILE "${CMAKE_CURRENT_BINARY_DIR}/LibGSF/LibGSFTargets.cmake"
        NAMESPACE libgsf::
    )
ENDIF()

CONFIGURE_FILE(cmake/LibGSFConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/LibGSF/LibGSFConfig.cmake"
    COPYONLY
)

set(ConfigPackageLocation lib/cmake/LibGSF)
install(EXPORT LibGSFTargets
    FILE LibGSFTargets.cmake
    NAMESPACE libgsf::
    DESTINATION ${ConfigPackageLocation}
)
install(
    FILES cmake/LibGSFConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/LibGSF/LibGSFConfigVersion.cmake"
    DESTINATION "${ConfigPackageLocation}"
)

