# 
# libsnapper
#
# Dependencies:
#  * OpenCV
#  * OpenMP (optional - used only by the program opencv_calibrate_stereo)
#  * boost (for ublas)
#  * lapack
#  * ulapack 
#  * libplankton 
#
PROJECT(libsnapper)

CMAKE_MINIMUM_REQUIRED(VERSION 2.8)

set(LIBSNAPPER_VERSION 20170105.0.0)

#--------------------------------#
# Enforce an out-of-source build #
#--------------------------------#

STRING(COMPARE EQUAL "${PROJECT_SOURCE_DIR}" "${PROJECT_BINARY_DIR}" INSOURCE)
IF(INSOURCE)
  MESSAGE(FATAL_ERROR "This project requires an out of source build. This is handled by the Makefile. Please type 'make'.")
ENDIF(INSOURCE)


#--------------------------------#
# Build Options                  #
#--------------------------------#

# this gets CMake to use the system triplet (x86_64-linux-gnu)
# for library locations
INCLUDE(GNUInstallDirs)

# Options can be set from the command line when running cmake.
#   eg. cmake . -DCMAKE_BUILD_TYPE=Release -DDEBUG_PROFILING=on

# Build types are: Release, Debug, RelWithDebInfo, MinSizeRel
IF( NOT CMAKE_BUILD_TYPE )
  SET( CMAKE_BUILD_TYPE Release CACHE STRING
       "Build type options are: None Debug Release RelWithDebInfo MinSizeRel."
       FORCE )
ENDIF( NOT CMAKE_BUILD_TYPE )

OPTION( USE_OPENMP "Use OpenMP" ON )

#-----------------------#
# Dependencies          #
#-----------------------#

# Boost 
FIND_PACKAGE(Boost COMPONENTS thread)
IF( NOT Boost_FOUND )
   MESSAGE( FATAL_ERROR  "ERROR - Can't find boost" )
ENDIF( NOT Boost_FOUND )

# lapack
FIND_PACKAGE(LAPACK REQUIRED)
IF( NOT LAPACK_FOUND )
   MESSAGE( FATAL_ERROR  "ERROR - Can't find lapack" )
ENDIF( NOT LAPACK_FOUND )

# OpenCV
FIND_PACKAGE(OpenCV REQUIRED)
IF ( NOT OpenCV_FOUND )
 MESSAGE(FATAL_ERROR "Error - Can't find OpenCV")
ENDIF( NOT OpenCV_FOUND )

# ulapack 
find_path(ULAPACK_INCLUDE_DIR matrix_types.hpp PATH_SUFFIXES ulapack)
SET( CMAKE_REQUIRED_INCLUDES ${ULAPACK_INCLUDE_DIR} ${Boost_INCLUDE_DIR} )
INCLUDE(CheckIncludeFileCXX)
CHECK_INCLUDE_FILE_CXX("matrix_types.hpp" HAVE_ULAPACK )
IF( NOT HAVE_ULAPACK )
    MESSAGE( FATAL_ERROR  "ERROR - Can't find ulapack - " ${ULAPACK_INCLUDE_DIR} )
ENDIF( NOT HAVE_ULAPACK )      

# libplankton 
FIND_PACKAGE(LibPlankton REQUIRED)
IF( NOT LibPlankton_FOUND )
   MESSAGE( FATAL_ERROR  "ERROR - Can't find libplankton" )
ENDIF( NOT LibPlankton_FOUND )

# OpenMP (optional for opencv_calibrate_stereo)
IF( USE_OPENMP )
   FIND_PACKAGE(OpenMP)
   IF( OPENMP_FOUND )
      SET( USE_OPENMP ON )
   ENDIF( OPENMP_FOUND )
ENDIF( USE_OPENMP )


#-----------------------#
# Compiler setup        #
#-----------------------#

ADD_DEFINITIONS( "-Wall" )

INCLUDE_DIRECTORIES( ${PROJECT_SOURCE_DIR}/include
                     ${OpenCV_INCLUDE_DIRS}
                     ${ULAPACK_INCLUDE_DIR}
                     ${Boost_INCLUDE_DIR} )

LINK_DIRECTORIES( ${OPENCV_LIBRARY_DIRS} )

#-----------------------#
# Print Some Info       #
#-----------------------#

MESSAGE( "" )
MESSAGE( "CONFIGURATION SUMMARY" )
MESSAGE( "---------------------" )
MESSAGE( "" )
MESSAGE( "CMAKE_BUILD_TYPE = '${CMAKE_BUILD_TYPE}'" )
MESSAGE( "" )
MESSAGE( "CMAKE_INSTALL_PREFIX = '${CMAKE_INSTALL_PREFIX}'" )
MESSAGE( "" )
MESSAGE( "USE_OPENMP = '${USE_OPENMP}'" )

IF( CMAKE_BUILD_TYPE STREQUAL Debug )
   MESSAGE( "CMAKE_CXX_FLAGS_DEBUG = '${CMAKE_CXX_FLAGS_DEBUG}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Debug )

IF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )
   MESSAGE( "CMAKE_CXX_FLAGS_RELWITHDEBINFO = '${CMAKE_CXX_FLAGS_RELWITHDEBINFO}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo )

IF( CMAKE_BUILD_TYPE STREQUAL Release )
   MESSAGE( "CMAKE_CXX_FLAGS_RELEASE = '${CMAKE_CXX_FLAGS_RELEASE}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL Release )

IF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )
   MESSAGE( "CMAKE_CXX_FLAGS_MINSIZEREL = '${CMAKE_CXX_FLAGS_MINSIZEREL}'" )
ENDIF( CMAKE_BUILD_TYPE STREQUAL MinSizeRel )

MESSAGE( "" )

#-----------------------#
# Build Instructions    #
#-----------------------#

# Locations for the library and binary files
SET( LIBRARY_OUTPUT_PATH     ${PROJECT_SOURCE_DIR}/lib )
SET( EXECUTABLE_OUTPUT_PATH  ${PROJECT_SOURCE_DIR}/bin )

ADD_SUBDIRECTORY(src)
ADD_SUBDIRECTORY(include)
ADD_SUBDIRECTORY(tests)
ADD_SUBDIRECTORY(tools)


#-----------------------#
# Testing Instructions  #
#-----------------------#

ENABLE_TESTING( )

ADD_TEST( stereo_calib_load_test   ${EXECUTABLE_OUTPUT_PATH}/stereo_calib_load_test ${PROJECT_SOURCE_DIR}/test_data/calib_full.txt )
ADD_TEST( triangulation_test       ${EXECUTABLE_OUTPUT_PATH}/triangulation_test     ${PROJECT_SOURCE_DIR}/test_data/calib_full.txt )
ADD_TEST( triangulate_points_test  ${EXECUTABLE_OUTPUT_PATH}/triangulate_points     ${PROJECT_SOURCE_DIR}/test_data/calib_full.txt ${PROJECT_SOURCE_DIR}/test_data/feature_data.txt )
ADD_TEST( camera_geometry_test     ${EXECUTABLE_OUTPUT_PATH}/camera_geometry_test   ${PROJECT_SOURCE_DIR}/test_data/calib_full.txt )

#-----------------------#
# Installation Related  #
#-----------------------#

INCLUDE(CMakePackageConfigHelpers)
WRITE_BASIC_PACKAGE_VERSION_FILE(
    "${CMAKE_CURRENT_BINARY_DIR}/LibSnapper/LibSnapperConfigVersion.cmake"
    VERSION ${LIBSNAPPER_VERSION}
    COMPATIBILITY AnyNewerVersion
)

IF(CMAKE_VERSION VERSION_LESS "3.0")
    EXPORT(TARGETS snapper
        FILE "${CMAKE_CURRENT_BINARY_DIR}/LibSnapper/LibSnapperTargets.cmake"
        NAMESPACE libsnapper::
    )
ELSE()
    EXPORT(EXPORT LibSnapperTargets
        FILE "${CMAKE_CURRENT_BINARY_DIR}/LibSnapper/LibSnapperTargets.cmake"
        NAMESPACE libsnapper::
    )
ENDIF()

CONFIGURE_FILE(cmake/LibSnapperConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/LibSnapper/LibSnapperConfig.cmake"
    COPYONLY
)

set(ConfigPackageLocation lib/cmake/LibSnapper)
install(EXPORT LibSnapperTargets
    FILE LibSnapperTargets.cmake
    NAMESPACE libsnapper::
    DESTINATION ${ConfigPackageLocation}
)
install(
    FILES cmake/LibSnapperConfig.cmake
    "${CMAKE_CURRENT_BINARY_DIR}/LibSnapper/LibSnapperConfigVersion.cmake"
    DESTINATION "${ConfigPackageLocation}"
)
